ECC189 spice model - anyone?
- Thread starter Habibi
- Start date
Help Support GroupDIY Audio Forum:
buildafriend
Well-known member
Maybe looking at a macro of a similar model could help you to design one?
I haven’t opened the Koren libs in a while but that would be the first place I would look. You might be able to contact him via email?
I haven’t opened the Koren libs in a while but that would be the first place I would look. You might be able to contact him via email?
PRR said:
I have been through DIYAudio and couldn't find anything. A search in that thread doesn't show a result for ecc189 or 6es8. I have not manually gone through all 100 pages yet though... will update if I find anything - unless you have already spotted it there?
Sorry.
Mock-up with 6DJ8, it will "work", but the numbers won't be exact.
Mock-up with 6DJ8, it will "work", but the numbers won't be exact.
Code:
**********************************************************************
* GENERIC: 6DJ8 / ECC88
* MODEL: 6DJ8
* NOTES: No grid current model
**********************************************************************
.SUBCKT 6DJ8 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.09 RAS= 0.2 CDO= 0
+ RAP= 0 ERP= 1.35
+ MU0= 33 MUR= 0.02 EMC= 0.0000795
+ GCO=-0.2 GCF= 0
+ CGA=1.40E-12 CGK=3.30E-12 CAK=1.80E-12
.ENDSI just noted that I gave parameters but not the TRIODENH model/math.
I have NOT worked with this model and do not know its quirks.
Code:
**********************************************************************
.SUBCKT TRIODENH A G K
+PARAMS: LIP=1 LIF=3.7E-3 RAF=18E-3 RAS=1 CDO=0 RAP=4E-3
+ ERP=1.5
+ MU0=17.3 MUR=19E-3 EMC=9.6E-6 GCO=0 GCF=213E-6
+ CGA=3.9p CGK=2.4p CAK=0.7p
************************************************************************
*
* Anode/grid model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
* LIP Conduction limit exponent
* LIF Conduction limit factor
* CDO Conduction offset
* RAF Anode resistance factor for neg grid voltages
* RAP Anode resistance factor for positive grid voltages
* ERP Emission power
* MU0 Mu between grid and anode at Vg=0
* MUR Mu reduction factor for large negative grid voltages
* EMC Emission coefficient
* GCO Grid current offset in volts
* GCF Grid current scale factor
*
************************************************************************
Elim LI 0 VALUE {PWR(LIMIT{V(A,K),0,1E6},{LIP})*{LIF}}
Egg GG 0 VALUE {V(G,K)-{CDO}}
Erpf RP 0 VALUE {1-PWR(LIMIT{-V(GG)*{RAF},0,0.999},{RAS})+LIMIT{V(GG),0,1E6}*{RAP}}
Egr GR 0 VALUE {LIMIT{V(GG),0,1E6}+LIMIT{(V(GG))*(1+V(GG)*{MUR}),-1E6,0}}
Eem EM 0 VALUE {LIMIT{V(A,K)+V(GR)*{MU0},0,1E6}}
Eep EP 0 VALUE {PWR(V(EM),ERP)*{EMC}*V(RP)}
Eel EL 0 VALUE {LIMIT{V(EP),0,V(LI)}}
Eld LD 0 VALUE {LIMIT{V(EP)-V(LI),0,1E6}}
Ga A K VALUE {V(EL)}
************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf GF 0 VALUE {PWR(LIMIT{V(G,K)-{GCO},0,1E6},1.5)*{GCF}}
Gg1 G K VALUE {(V(GF)+V(LD))}
* gf
*
* Capacitances and anti-float resistors
*
CM1 G K {CGK}
CM2 A G {CGA}
CM3 A K {CAK}
RF1 A 0 1000MEG
RF2 G 0 1000MEG
RF3 K 0 1000MEG
.ENDS
**********************************************************************I have NOT worked with this model and do not know its quirks.
