3f4 spice model for 12AV7

[NewYorkDave]

In response to a request I made elsewhere, here is a 12AV7 model by Mr. Robert Casey. I've tried it out in Circuitmaker with some circuits I've built in real life, and the simulated performance has been very close to how the real circuits behaved.
--------------------------------------------------------------


*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12Av7A A G K
* ANODE MODEL
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037
BGG GG 0 V=V(G)-V(K)--0.5
BRP1 RP1 0 V=URAMP(-V(GG)* 0.09869 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 25.093 )
BEP EP 0 V=(V(EM)^ 1.4 )*V(RP)* 0.00001863
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
* GRID MODEL
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012
BG G K I=V(GF)+V(LD)
* CAPS
CAK A K 0.00000000000024
CGK G K 0.00000000000323
CGA G A 0.0000000000019
.ENDS X12Av7A

 

[Guest]

Thanks alot. This is different than most of the other models I have collected.

 

[NewYorkDave]

Mr. Casey tweaked the model a bit. Here's the updated version.
----------------------------------------------------------------------------
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12Av7A A G K
* ANODE MODEL
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037
BGG GG 0 V=V(G)-V(K)--0.5
*below is variation of grid slopes
BRP1 RP1 0 V=URAMP(-V(GG)* 0.07069 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 28.093 )
BEP EP 0 V=(V(EM)^ 1.4 )*V(RP)* 0.00001963
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
* GRID MODEL
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012
BG G K I=V(GF)+V(LD)
* CAPS
CAK A K 0.00000000000024
CGK G K 0.00000000000323
CGA G A 0.0000000000019
.ENDS X12Av7A

----------------------------------------------------------------
He also came up with this 12AY7 model
-----------------------------------------------------------------
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12Ay7A A G K
* ANODE MODEL
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037
BGG GG 0 V=V(G)-V(K)--0.5
*below is variation of grid slopes
BRP1 RP1 0 V=URAMP(-V(GG)* 0.009869 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))
*below is grid sensitivity
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 45.093 )
*below ^is grid linearity,*plate current at 0Vg
BEP EP 0 V=(V(EM)^ 1.3 )*V(RP)* 0.000007503
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
* GRID MODEL
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012
BG G K I=V(GF)+V(LD)
* CAPS
CAK A K 0.0000000000006
CGK G K 0.0000000000013
CGA G A 0.0000000000013
.ENDS X12Ay7A

 

[Kev]

Thanks Dave,
much appreciated