12AY7 spice model?

Does anybody have a spice model for this?
I have models for several tubes, but the 12AY7 not among them...

JH.

In response to a request I posted elsewhere, Mr. Robert Casey kindly provided the following 3f4 SPICE models. The 12AV7 model has been very accurate for me so far; the simulated behavior has corresponded closely to the real behavior of circuits I've buit. I haven't used the 12AY7 model yet but if it works as well as the AV7 model, then it's a winner.

12AV7
----------------------------------------------------------------------------
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12Av7A A G K
* ANODE MODEL
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037
BGG GG 0 V=V(G)-V(K)--0.5
*below is variation of grid slopes
BRP1 RP1 0 V=URAMP(-V(GG)* 0.07069 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 28.093 )
BEP EP 0 V=(V(EM)^ 1.4 )*V(RP)* 0.00001963
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
* GRID MODEL
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012
BG G K I=V(GF)+V(LD)
* CAPS
CAK A K 0.00000000000024
CGK G K 0.00000000000323
CGA G A 0.0000000000019
.ENDS X12Av7A

----------------------------------------------------------------

12AY7
-----------------------------------------------------------------
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)
.SUBCKT X12Ay7A A G K
* ANODE MODEL
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037
BGG GG 0 V=V(G)-V(K)--0.5
*below is variation of grid slopes
BRP1 RP1 0 V=URAMP(-V(GG)* 0.009869 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))
*below is grid sensitivity
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 45.093 )
*below ^is grid linearity,*plate current at 0Vg
BEP EP 0 V=(V(EM)^ 1.3 )*V(RP)* 0.000007503
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
* GRID MODEL
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012
BG G K I=V(GF)+V(LD)
* CAPS
CAK A K 0.0000000000006
CGK G K 0.0000000000013
CGA G A 0.0000000000013
.ENDS X12Ay7A

Thank you, Dave; I 'll try this!

JH.